* * *  S W O R T      dbase-Programmsystem zur Verwaltung
* * *                 von Stichworten }ber Zeitschriften-
* * *  artikel. SWORT ist das zentrale Modul mit den
* * *  Initialisierungen und der Men}-Auswahl.


CLEAR
SET TALK OFF
SET BELL OFF
SET INTENSITY OFF

IF FILE("B:ZNAM.MEM")
  RESTORE FROM B:ZNAM
 ELSE
  STORE 0 TO HV
  DO WHILE HV < 10
    STORE "Z" + STR(HV,1) TO ZS
    STORE "                       " TO &ZS
    STORE HV + 1 TO HV
  ENDDO
SAVE TO B:ZNAM
ENDIF

STORE F TO PROGEND
USE B:SWORT

DO WHILE .NOT. PROGEND
  ERASE
  SELECT PRIMARY
  SET COLON OFF

  @ 2,20 SAY "Stichwort-Verwaltungs-Programm"
  @ 3,20 SAY "=============================="
  @ 7,20 SAY  "1 - Stichworte erfassen"
  @ 8,20 SAY  "2 - Stichworte {ndern"
  @ 10,20 SAY "3 - Stichwort suchen"
  @ 11,20 SAY "4 - Gesamtliste ausdrucken"
  @ 13,20 SAY "5 - Zeitschriftennamen erfassen"
  @ 14,20 SAY "6 - Zeitschriftennamen drucken"
  @ 16,20 SAY "E - Programmende"
  @ 19,20 SAY "Entsprechende Taste bet{tigen:"

  STORE F TO OK

  DO WHILE .NOT. OK
    STORE " " TO EINGABE
    @ 19,51 GET EINGABE
    READ
    SET COLON ON
    STORE T TO OK
    DO CASE
      CASE EINGABE="1"
        DO B:SWERF
      CASE EINGABE="2"
        GO TOP
        BROWSE
      CASE EINGABE="3"
        DO B:SWSUCH
      CASE EINGABE="4"
        DO B:SWLIST
      CASE EINGABE="5"
        ERASE
        @ 2,20 SAY "Zeitschriftennamen erfassen"
        @ 3,20 SAY "==========================="
        STORE 0 TO HV
        DO WHILE HV < 10
          STORE "Z"+STR(HV,1) TO ZS
          @ HV + 6,20 SAY STR(HV,1) + " = " GET &ZS
          STORE HV + 1 TO HV
        ENDDO
        READ
        SAVE TO B:ZNAM
      CASE EINGABE="6"
        ERASE
        SET PRINT ON
        ? "                 Zeitschriftennamen"
        ? "                 =================="
        ?
        STORE 0 TO HV
        DO WHILE HV < 10
          STORE "Z" + STR(HV,1) TO ZS
          IF &ZS <> "     "
            ? STR(HV,16) + " = " + &ZS
          ENDIF
          STORE HV + 1 TO HV
        ENDDO
        ?
        SET PRINT OFF
      CASE ! (EINGABE)="E"
        STORE T TO PROGEND
      OTHERWISE
        STORE F TO OK
        SET COLON OFF
        @ 19,51 SAY CHR(7)
    ENDCASE
  ENDDO
ENDDO
CLEAR
